#
# shrink the freedb-XY.tar file
#
# ! 1. Replace multiple binary NULLs etc. from tar 
# by PROMPT> tar -xOf xy.tar > xy-tar.txt 
#
#
# mark begin of record
#
s/# xmcd.*/X/g
#
s/#[ \t]*$//g
#
# remove bla bla
#
s/# Track frame offsets.*$//g
s/# Revision.*$//g
s/# Processed.*$//g
s/# Submitted.*$//g
s/# Copyright.*$//g
s/# Generated.*$//g
s/PLAYORDER=.*//g
#
#
#
s/#[	 ]*\([0-9][0-9]*\).*/T \1/g
s/# Disc length: \([0-9][0-9]*\).*/L \1/g
#s/DISCID=\([0-9a-fA-F][0-9a-fA-F]*\).*/I \1/g
s/DISCID=\([0-9a-fA-F][0-9a-fA-F]*.*\)/I \1/g
s/DTITLE=\(.*\)/D \1/g
s/DYEAR=[ \t]*$//g
s/DYEAR=\(.*\)/Y \1/g
s/DGENRE=[ \t]*$//g
s/DGENRE=\(.*\)/G \1/g
#
# 'T' as Track already used, 'S' might be interpretet as 'Song'
#  
s/TTITLE\([0-9][0-9]*\)=\(.*\)/S \1 \2/g
s/EXTD=[ \t]*$//g
s/EXTD=\(.*\)/x \1/g
#
# Remove empty lines
#
s/EXTT\([0-9][0-9]*\)=[ \t]*$//g
#
# Keep non-empty
#
s/EXTT\([0-9][0-9]*\)=\(.*\)/E \1 \2/g
#
# finally remove lines with seldom patterns. I found two:
#	#  WSPse...
#       #blues,classical,country...
s/#.*$//g
#
# delete empty lines
#
/^$/d