dltodo.cmd als HTML-Datei
|
dltodo.cmd als HTML-Datei |
|
Zum Menüeintrag 'Skripte etc.' - Druck-/Layout-Infos (hier: Quer-Format) - Stand: 30.09.2006
@echo off
REM Definiere das aktuelle Datum als MMonatTTag der Skripte.
REM Ein nachfolgender Buchstabe signalisiert mehrere Versionen
REM an einem Tag (b = 2. Version, c = 3. Version etc.).
REM ---
SET MMTT=0927
REM Kontrollwert zum aktuellen Datum der Datei 'umfang.txt'
REM ---
SET DATUMUTXT=000_DATUM=22.09.06
REM ---Doku-
REM Definiere Variablen zu -- Datum und Uhrzeit
SET JJMMTT=%date:~9,4%-%date:~6,2%-%date:~3,2%
SET JJMMTT=%JJMMTT: =0%
SET SSMMSS=%time:~0,2%-%time:~3,2%-%time:~6,2%
SET SSMMSS=%SSMMSS: =0%
REM Definiere Variablen zu -- WGET
SET WGET_URL=http://xoomer.virgilio.it/hherold
SET WGET_ZIP=wget-1.10.2b.zip
SET WGET_VER=1_10_2
SET WGET_EXE=$OEM$\Tools\WGET\%WGET_VER%\wget.exe
IF NOT EXIST 5:\$OEM$\Tools\WGET\%WGET_VER% MKDIR 5:\$OEM$\Tools\WGET\%WGET_VER% >NUL
REM Definiere Variablen zu -- UNZIP
SET UNZIP_URL=ftp://ftp.info-zip.org/pub/infozip/WIN32
SET UNZIP_ZIP=unz552xn.exe
SET UNZIP_VER=5_52
SET UNZIP_EXE=$OEM$\Tools\Unzip\%UNZIP_VER%\unzip.exe
IF NOT EXIST 5:\$OEM$\Tools\Unzip\%UNZIP_VER% MKDIR 5:\$OEM$\Tools\Unzip\%UNZIP_VER% >NUL
REM Erstelle für Protokolldateien den Ordner ...
IF NOT EXIST "%userprofile%\nt_adui" MKDIR "%userprofile%\nt_adui"
IF NOT EXIST 5:\ GOTO :EndeLW
IF NOT EXIST %WGET_EXE% GOTO :EndeWGET
IF EXIST 5:\DLURLtemp RMDIR /S /Q 5:\DLURLtemp
IF EXIST 5:\DLURLNEUtemp RMDIR /S /Q 5:\DLURLNEUtemp
:UNZIP
IF EXIST %UNZIP_EXE% GOTO :Projektanpassung
ECHO.
ECHO Lade und entpacke UNZIP-Programm ...
ECHO.
IF NOT EXIST 5:\$OEM$\Tools\Unzip\%UNZIP_ZIP% 5:\%WGET_EXE% -c -q -P 5:\$OEM$\Tools\Unzip
%UNZIP_URL%/%UNZIP_ZIP%
5:\$OEM$\Tools\Unzip\%UNZIP_ZIP% -d 5:\$OEM$\Tools\Unzip\%UNZIP_VER%
ECHO.
ECHO. Ok.
ECHO.
REM ca. 3 Sekunden Pause
%windir%\system32\PING.EXE -n 3 127.0.0.1 >NUL
:Projektanpassung
REM ':Projektanpassung' wurde ins Projekt eingefügt,
REM um nachträglich Korrekturen durchzuführen.
IF EXIST 5:\$OEM$\$1\UPDATES\100_MBSA XCOPY 5:\$OEM$\$1\UPDATES\100_MBSA
5:\$OEM$\$1\UPDATES\110_MBSA /i >NUL
IF EXIST 5:\$OEM$\$1\UPDATES\100_MBSA RMDIR /S /Q 5:\$OEM$\$1\UPDATES\100_MBSA
IF EXIST 5:\$OEM$\$1\UPDATES\110_Script XCOPY 5:\$OEM$\$1\UPDATES\110_Script
5:\$OEM$\$1\UPDATES\100_WScript /i >NUL
IF EXIST 5:\$OEM$\$1\UPDATES\110_Script RMDIR /S /Q 5:\$OEM$\$1\UPDATES\110_Script
IF EXIST 5:\$OEM$\Tools\CDimage XCOPY 5:\$OEM$\Tools\CDimage 5:\$OEM$\Tools\ISO /i /y >NUL
IF EXIST 5:\$OEM$\Tools\CDimage RMDIR /S /Q 5:\$OEM$\Tools\CDimage
IF EXIST 5:\$OEM$\Tools\Unzip\fun*.* DEL /Q 5:\$OEM$\Tools\Unzip\fun*.*
IF EXIST 5:\$OEM$\Tools\Unzip\Lic*.* DEL /Q 5:\$OEM$\Tools\Unzip\Lic*.*
IF EXIST 5:\$OEM$\Tools\Unzip\rea*.* DEL /Q 5:\$OEM$\Tools\Unzip\rea*.*
IF EXIST 5:\$OEM$\Tools\Unzip\sfx*.* DEL /Q 5:\$OEM$\Tools\Unzip\sfx*.*
IF EXIST 5:\$OEM$\Tools\Unzip\unzip*.* DEL /Q 5:\$OEM$\Tools\Unzip\unzip*.*
IF EXIST 5:\$OEM$\Tools\Unzip\whe*.* DEL /Q 5:\$OEM$\Tools\Unzip\whe*.*
IF EXIST 5:\$OEM$\Tools\Unzip\zip*.* DEL /Q 5:\$OEM$\Tools\Unzip\zip*.*
IF EXIST 5:\$OEM$\Tools\news*.* DEL /Q 5:\$OEM$\Tools\news*.*
IF EXIST 5:\$OEM$\Tools\read*.* DEL /Q 5:\$OEM$\Tools\read*.*
IF EXIST 5:\$OEM$\Tools\samp*.* DEL /Q 5:\$OEM$\Tools\samp*.*
IF EXIST 5:\$OEM$\Tools\wget.h* DEL /Q 5:\$OEM$\Tools\wget.h*
:SP4check
REM Prüfe, ob Service Pack 4 in Datenbestände integriert wurde
IF EXIST 5:\i386\SP4.cat GOTO :DLLOG
ECHO.
ECHO Sie haben das Service Pack 4 noch nicht integriert.
ECHO Das Slipstreaming vom SP4 wird dringend empfohlen.
ECHO.
:DLLOG
REM Die Protokoll-Datei wird definiert ...
SET LOG=%TEMP%\DLLOG.TXT
REM Die Protokoll-Datei wird erstellt ...
ECHO. Datum: %DATE% >%LOG%
ECHO. Start: %TIME% >>%LOG%
ECHO. Vorgang: Download-Kontrolle >>%LOG%
:ONLINEcheck
IF EXIST 5:\$OEM$\1.txt DEL 5:\$OEM$\1.txt
REM Lade die Datei 1.txt, um die Server-Erreichbarkeit zu prüfen
REM Beende das Skript, falls nicht erreichbar
5:\%WGET_EXE% -q --no-cache -P 5:\$OEM$ http://home.arcor.de/jterlinden/1.txt
IF ERRORLEVEL 1 (
ECHO.
ECHO Der WEB-Server ist NICHT erreichbar! Sind Sie online?
ECHO.
ECHO. Im Moment stehen NUR DIE Optionen zur Verfuegung,
ECHO. die auch OFFLINE genutzt werden koennen.
ECHO. Stellen Sie sicher, dass alle aktuellen Downloads UND
ECHO. Skripte vorliegen.
GOTO :WAHL
)
:SKRIPTcheck
REM Die Datei dlu_MMTT.check wird IMMER geladen. So wird geprüft,
REM ob Sie mit den neuesten Skripten arbeiten. Ist diese Datei
REM auf dem WEB-SERVER NICHT mehr vorhanden, kann sie nicht mehr
REM geladen werden. Dann wird zur Sprungmarke ':EndeSKRIPTE'
REM gewechselt und die neueste Skripte.zip geladen.
IF EXIST 5:\dlu_%MMTT%.check DEL 5:\dlu_*.check
REM Lade dlu_%MMTT%.check
5:\%WGET_EXE% -q --no-cache -P 5:\ http://home.arcor.de/jterlinden/dlu_%MMTT%.check
IF NOT EXIST 5:\dlu_%MMTT%.check GOTO :EndeSKRIPTE
REM Die Datei dlu_temp.cmd beinhaltet Downloads nur temporär.
REM Liegt sie auf dem SERVER mit ANDEREM DATUM vor, wird
REM sie automatisch neu geladen.
5:\%WGET_EXE% -N -q --no-cache -P 5:\ http://home.arcor.de/jterlinden/dlu_temp.cmd
REM Die Datei dlu.cmd beinhaltet alle regulären Downloadadressen und
REM weitere Steuerungsbefehle. Fehlt sie, dann wird zur Sprungmarke
REM ':EndeSKRIPTE' gewechselt und die neueste Skripte.zip geladen.
IF NOT EXIST 5:\dlu.cmd GOTO :EndeSKRIPTE
:UTXTcheck
REM Es wird geprüft, ob 'umfang.txt' mit dem bei
REM 'SET DATUMUTXT=' genannten Datum vorliegt.
IF NOT EXIST 5:\$OEM$\$1\Updates\Skripte_NEU\umfang.txt GOTO :EndeSKRIPTE
IF NOT EXIST 5:\$OEM$\$1\Updates\umfang.txt COPY 5:\$OEM$\$1\Updates\Skripte_NEU\umfang.txt
5:\$OEM$\$1\Updates
FIND /i "%DATUMUTXT%" 5:\$OEM$\$1\Updates\umfang.txt >NUL
IF NOT ERRORLEVEL 1 (GOTO :WAHL) ELSE (GOTO :EndeUMFANGtxt)
REM -Doku---
:WAHL
TITLE - STARTDATEI - Downloads und Mehr zu Windows 2000 SP4
IF EXIST 5:\$OEM$\1.txt (
ECHO.
ECHO. Die Updates, die auf http://home.arcor.de/jterlinden/w2ksp4.htm
ECHO. ein farblich unterlegtes Datum haben, sind MANUELL zu laden.
ECHO.
ECHO. Aktueller DOWNLOAD-Umfang ist:
FIND /i "_=" 5:\$OEM$\$1\Updates\umfang.txt
ECHO.
ECHO Auswahl:
ECHO --------
ECHO.
ECHO. [D] DOWNLOADS - Stand per %MMTT% = MMonatTTag
)
ECHO.
ECHO.
ECHO. [W] WINDOWS - Update-Status kontrollieren oder aktualisieren
ECHO.
ECHO. [I] ISO - Generiere ISO-Datei zum Erstellen einer neuen W2k-Boot-CD
ECHO.
ECHO.
ECHO. [Q] Quit/Ende
ECHO.
ECHO.
:Auswahl
SET /p Eingabe= Ihre Auswahl bitte:
IF /i '%Eingabe%'=='d' GOTO :DOWNLOADS
IF /i '%Eingabe%'=='w' GOTO :WINUP
IF /i '%Eingabe%'=='i' GOTO :IMAGE
IF /i '%Eingabe%'=='q' GOTO :QUIT
GOTO :Auswahl
:DOWNLOADS
MKDIR 5:\DLURLtemp
ECHO --------- >>%LOG%
ECHO. Umfang: Updates laut "%PfadWinCD%\$OEM$\$1\UPDATES\UMFANG.TXT" >>%LOG%
ECHO. : >>%LOG%
START /MAX /WAIT CALL 5:\dlu.cmd
GOTO :TOOLS
:WINUP
DEL %LOG%
cls
5:\$OEM$\$1\Updates\updaten.cmd
EXIT
:IMAGE
DEL %LOG%
CLS
5:\isobuild.cmd
EXIT
:QUIT
DEL %LOG%
EXIT
REM ---Doku-
:TOOLS
ECHO Einen Moment bitte ...
REM Lade und entpacke Hilfsprogramme ...
:PSSHUTDOWN
IF EXIST 5:\$OEM$\$$\system32\PsShutdown.exe GOTO :SC
5:\%WGET_EXE% -N -q -P 5:\$OEM$\$$\system32 http://download.sysinternals.com/files/PsTools.zip
5:\%unzip_exe% -o 5:\$OEM$\$$\system32\PsTools.zip -d 5:\$OEM$\$$\system32\
:SC
IF EXIST 5:\$OEM$\$$\system32\SC.exe GOTO :SC_INFOS
IF NOT EXIST 5:\$OEM$\$$\system32\sc.zip 5:\%WGET_EXE% -N -q -P 5:\$OEM$\$$\system32 http://www.dynawell.com/reskit/microsoft/win2000/sc.zip
5:\%unzip_exe% -o -q 5:\$OEM$\$$\system32\sc.zip -d 5:\$OEM$\$$\system32\
:SC_INFOS
IF EXIST 5:\$OEM$\$$\system32\SC_INFOS.txt GOTO :SVC2KXP
IF NOT EXIST 5:\$OEM$\$$\system32\sc_infos.zip 5:\%WGET_EXE% -q -P 5:\$OEM$\$$\system32 http://home.arcor.de/jterlinden/sc_infos.zip
5:\%unzip_exe% -o -q 5:\$OEM$\$$\system32\sc_infos.zip -d 5:\$OEM$\$$\system32\
:SVC2KXP
5:\%WGET_EXE% -N -o 5:\$OEM$\$$\system32\svc_neu.log -nv -P 5:\$OEM$\$$\system32 http://www.ntsvcfg.de/svc2kxp.zip
5:\%unzip_exe% -o -q 5:\$OEM$\$$\system32\svc2kxp.zip -d 5:\$OEM$\$$\system32\
FIND /i "svc2kxp.zip" "%PfadWinCD%\$OEM$\$$\system32\svc_neu.log" >NUL
IF ERRORLEVEL 1 (
GOTO :TOOLSok
) ELSE (
ECHO --------- >>%LOG%
ECHO. Das Dienstekonfigurations-Skript 'svc2kxp.cmd' wurde neu geladen. >>%LOG%
ECHO. Bitte schauen Sie sich die Datei "svc2kxp_history.txt" >>%LOG%
ECHO. im Ordner "%PfadWinCD%\$OEM$\$$\system32\" an. >>%LOG%
ECHO. Diese Datei beinhaltet die Korrekturen. >>%LOG%
)
:TOOLSok
:Dateioperationen
IF EXIST 5:\$OEM$\$$\system32\pdh.dll DEL 5:\$OEM$\$$\system32\pdh.dll
IF EXIST 5:\$OEM$\$$\system32\psshut*.zip DEL /q 5:\$OEM$\$$\system32\psshut*.zip
CALL:MOVE history.txt svc2kxp_history.txt
CALL:MOVE license_sc.txt sc_license.txt
CALL:MOVE scdev.doc sc_infos.doc
CALL:MOVE scdev.txt sc_infos.txt
CALL:MOVE readme.txt PsTools_Readme.txt
GOTO :ENDE
:MOVE
IF EXIST 5:\$OEM$\$$\system32\%1 MOVE /Y 5:\$OEM$\$$\system32\%1 5:\$OEM$\$$\system32\%2
GOTO :EOF
:ENDE
REM Die Kontrolle ist abgeschlossen.
REM Alle Vorgänge stehen in einer Protokolldatei, die nun geladen wird.
REM Vorher werden noch abschließende Zeilen hineingeschrieben.
ECHO --------- >>%LOG%
ECHO. ENDE: %TIME% >>%LOG%
ECHO --------- >>%LOG%
:OPEN_PROTOKOLL
REM Kopiere/Öffne Protokolldatei ...
COPY %TEMP%\DLLOG.TXT "%userprofile%\nt_adui\%JJMMTT%_%SSMMSS%_DL.LOG" >NUL
START /MAX %TEMP%\DLLOG.TXT
EXIT
:EndeLW
ECHO ---------
ECHO - FEHLER: Virtuelles Laufwerk 5:\ existiert nicht
ECHO.
ECHO. Sie MUESSEN die Datei DLSTART.CMD aufrufen.
ECHO. Bitte BEARBEITEN Sie ggf. zuerst diese Datei - Infos siehe dort.
ECHO.
ECHO.
PAUSE
EXIT
:EndeWGET
ECHO --------- >%TEMP%\WGET.TXT
ECHO - FEHLER: Programm 'WGET' fehlt oder ist NICHT aktuell! >>%TEMP%\WGET.TXT
ECHO. >>%TEMP%\WGET.TXT
IF EXIST 5:\$OEM$\Tools\Wget.exe (
MOVE /Y 5:\$OEM$\Tools\Wget.exe 5:\$OEM$\Tools\Wget\Wgetonly.exe
MOVE /Y 5:\$OEM$\Tools\???eay32.dll 5:\$OEM$\Tools\Wget\ >NUL 2>NUL
)
IF EXIST 5:\$OEM$\Tools\Wget\Wgetonly.exe (
ECHO.
ECHO. Lade 'Wget' in [neuer] Version '%WGET_VER%' ...
5:\$OEM$\Tools\Wget\Wgetonly.exe -c -q -P 5:\$OEM$\Tools\Wget %WGET_URL%/%WGET_ZIP%
)
IF EXIST 5:\$OEM$\Tools\Wget\%WGET_ZIP% (
ECHO. Das aktuelle Archiv %WGET_ZIP% ist hier vorhanden: >>%TEMP%\WGET.TXT
ECHO. %PfadWinCD%\$OEM$\Tools\Wget\ >>%TEMP%\WGET.TXT
IF NOT EXIST 5:\%UNZIP_EXE% GOTO :WGETentpacken
5:\%UNZIP_EXE% -o -q 5:\$OEM$\Tools\WGET\%WGET_ZIP% -d 5:\$OEM$\Tools\WGET\%WGET_VER%
ECHO. Das WGET-Archiv wurde entpackt nach: >>%TEMP%\WGET.TXT
ECHO. %PfadWinCD%\$OEM$\Tools\Wget\%WGET_VER%\ >>%TEMP%\WGET.TXT
COPY /Y 5:\$OEM$\Tools\WGET\%WGET_VER%\Wget.exe 5:\$OEM$\Tools\Wget\Wgetonly.exe
COPY /Y 5:\$OEM$\Tools\WGET\%WGET_VER%\???eay32.dll 5:\$OEM$\Tools\Wget\
ECHO WGETONLY.EXE und ???eay32.dll dienen NUR dem Laden einer neuen WGET-Version!
>5:\$OEM$\Tools\Wget\Wgetonly.txt
ECHO. Bitte rufen Sie DLSTART.CMD erneut auf. >>%TEMP%\WGET.TXT
GOTO :WGETentpackt
)
ECHO. Kopieren Sie folgende URL in den Browser, um 'wget' zu laden: >>%TEMP%\WGET.TXT
ECHO. %WGET_URL%/%WGET_ZIP% >>%TEMP%\WGET.TXT
ECHO. >>%TEMP%\WGET.TXT
ECHO. Speichern Sie das ZIP-Archiv in diesem Ordner: >>%TEMP%\WGET.TXT
ECHO. %PfadWinCD%\$OEM$\Tools\WGET >>%TEMP%\WGET.TXT
:WGETentpacken
ECHO. >>%TEMP%\WGET.TXT
ECHO. Entpacken Sie das ZIP-Archiv in diesen Unter-Ordner: >>%TEMP%\WGET.TXT
ECHO. %PfadWinCD%\$OEM$\Tools\WGET\%WGET_VER% >>%TEMP%\WGET.TXT
:WGETentpackt
ECHO. >>%TEMP%\WGET.TXT
ECHO. Webseite zu WGET: >>%TEMP%\WGET.TXT
ECHO. http://www.gnu.org/software/wget/wget.html >>%TEMP%\WGET.TXT
ECHO --------- >>%TEMP%\WGET.TXT
ECHO. ENDE: %DATE% - %TIME% >>%TEMP%\WGET.TXT
ECHO --------- >>%TEMP%\WGET.TXT
REM Kopiere/Öffne Protokolldatei ...
COPY %TEMP%\WGET.TXT "%userprofile%\nt_adui\%JJMMTT%_%SSMMSS%_WGET.LOG"
START /MAX %TEMP%\WGET.TXT
EXIT
:EndeUMFANGtxt
ECHO --------- >>%LOG%
ECHO - FEHLER: Datei 'umfang.txt' ist falsch >>%LOG%
ECHO. >>%LOG%
ECHO. Bitte vergleichen Sie die Inhalte von 'umfang.txt'. >>%LOG%
ECHO. Bringen Sie 'umfang.txt' in ..\$OEM$\$1\Updates >>%LOG%
ECHO. MANUELL auf den Stand von ..\$OEM$\$1\Updates\Skripte_NEU >>%LOG%
ECHO. >>%LOG%
ECHO. Passen Sie insbesondere den Wert bei '000_DATUM=' an. >>%LOG%
ECHO. >>%LOG%
ECHO. Bitte starten Sie danach 'dlstart.cmd' erneut. >>%LOG%
ECHO --------- >>%LOG%
ECHO. ENDE: %TIME% >>%LOG%
ECHO --------- >>%LOG%
REM Kopiere/Öffne Protokolldatei ...
COPY %TEMP%\DLLOG.TXT "%userprofile%\nt_adui\%JJMMTT%_%SSMMSS%_U-txt.LOG"
START /MAX %TEMP%\DLLOG.TXT
EXIT
:EndeSKRIPTE
ECHO --------- >>%LOG%
ECHO - FEHLER: Nicht aktuelle oder fehlende Skripte >>%LOG%
ECHO. >>%LOG%
ECHO. Sie scheinen NICHT mit den aktuellen Skripten zu arbeiten oder >>%LOG%
ECHO. es fehlt eine Skriptdatei. Die neue Skripte.zip wurde geladen >>%LOG%
ECHO. und automatisch entpackt. Die Skripte wurden kopiert. >>%LOG%
ECHO. >>%LOG%
ECHO. Bitte rufen Sie 'dlstart.cmd' erneut auf. >>%LOG%
ECHO.
DEL 5:\dlu_0*.cmd >NUL 2>NUL
IF EXIST 5:\$OEM$\$1\Updates\Skripte_NEU\skripte.zip DEL 5:\$OEM$\$1\Updates\Skripte_NEU\skripte.zip
5:\%WGET_EXE% -q --no-cache -P 5:\$OEM$\$1\Updates\Skripte_NEU http://home.arcor.de/jterlinden/skripte.zip
5:\%UNZIP_EXE% -o -q 5:\$OEM$\$1\Updates\Skripte_NEU\skripte.zip -d 5:\$OEM$\$1\Updates\Skripte_NEU\
REM Kopiere Skripte ...
COPY /Y 5:\$OEM$\$1\Updates\Skripte_NEU\erweit*.cmd 5:\$OEM$\$1\Updates
COPY /Y 5:\$OEM$\$1\Updates\Skripte_NEU\patche*.cmd 5:\$OEM$\$1\Updates
COPY /Y 5:\$OEM$\$1\Updates\Skripte_NEU\update*.cmd 5:\$OEM$\$1\Updates
COPY /Y 5:\$OEM$\$1\Updates\Skripte_NEU\iso*.cmd 5:\
COPY /Y 5:\$OEM$\$1\Updates\Skripte_NEU\dlu*.cmd 5:\
ECHO --------- >>%LOG%
ECHO. ENDE: %TIME% >>%LOG%
ECHO --------- >>%LOG%
REM Kopiere/Öffne Protokolldatei ...
COPY %TEMP%\DLLOG.TXT "%userprofile%\nt_adui\%JJMMTT%_%SSMMSS%_Skripte.LOG"
START /MAX %TEMP%\DLLOG.TXT
COPY /Y 5:\$OEM$\$1\Updates\Skripte_NEU\dlt*.cmd 5:\
EXIT
Jürgen Terlinden - Feedback