erweit02.cmd als HTML-Datei

Zum Menüeintrag 'Skripte etc.'   -   Druck-/Layout-Infos (hier: Quer-Format)   -   Stand: 30.09.2006

@echo off
TITLE Installiere Erweiterungen zu Win2000-SP4 - Letzter Teil

REM Definiere den Pfad zu den Update-Dateien
SET PfadUpdates=%systemdrive%\Updates

REM Setze die Variable 'PfadUTXT' für den Pfad zur Datei 'umfang.txt'
REM Entweder Diskettenlaufwerk A: oder der oben per 'SET PfadUpdates='
REM definierte Pfad zu den Update-Dateien
DIR A:\umfang.txt >NUL 2>NUL
IF NOT ERRORLEVEL 1 (SET PfadUTXT=A:\) ELSE (SET PfadUTXT=%PfadUpdates%)

ECHO.
ECHO. Setze die Installation von Erweiterungen fort ...
ECHO.

:DIRECTX
FIND /i "060_DIRECTX___=JA" %PfadUTXT%\umfang.txt >NUL
IF ERRORLEVEL 1 GOTO :NET_FW_20
ECHO Installiere DirectX 9.0c
ECHO Dies dauert etwas. Bitte warten ...
START /WAIT %PfadUpdates%\060_DirectX90c\directx_9c_redist.exe /q /t:%PfadUpdates%\060_DirectX90c\Temp
START /WAIT %PfadUpdates%\060_DirectX90c\Temp\dxsetup.exe /silent
RMDIR /S /Q %PfadUpdates%\060_DirectX90c\Temp
ECHO. OK.

:NET_FW_20
REM REG-Zweig:
REM [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\NET Framework Setup]

FIND /i "130_NET_FW_20_=JA" %PfadUTXT%\umfang.txt >NUL
IF ERRORLEVEL 1 GOTO :RMU
ECHO.
ECHO NET Framework 2.0 - Teil 1 von 2 - Installiere Basispaket
ECHO Dieser Vorgang dauert etliche Minuten. Bitte warten ...
START /WAIT %PfadUpdates%\130_NETFramework\V2\dotnetfx.exe /q /c:"install.exe /qb /lang 1031"
ECHO. OK.
ECHO.
ECHO NET Framework 2.0 - Teil 2 von 2 - Installiere Sprachpaket
START /WAIT %PfadUpdates%\130_NETFramework\V2\langpack.exe /q /c:"install.exe /qb"
ECHO. OK.

:RMU
FIND /i "140_RMADDONIE_=JA" %PfadUTXT%\umfang.txt >NUL
IF ERRORLEVEL 1 GOTO :ENDE
ECHO.
ECHO Installiere Internet Explorer 6 Add-On zur Windows-Rechteverwaltung
START /WAIT %PfadUpdates%\140_RM\RMUsetup.exe /c:"setup.exe /qb"
ECHO. OK.

:ENDE
REM De-Aktiviere das von .NET-Framework angelegte Benutzerkonto ASPNET
NET USER ASPNET /active:no >NUL 2>NUL

COPY %PfadUpdates%\patches.cmd "%ALLUSERSprofile%\Startm~1\Programme\Autostart" >NUL
%windir%\system32\psshutdown.exe -r -t 12 -m "Der PC MUSS neu gestartet werden. Die Installation wird danach fortgesetzt."
DEL "%ALLUSERSprofile%\Startm~1\Programme\Autostart\erweit02.cmd"
EXIT

Jürgen Terlinden  -  Feedback