isobuild.cmd als HTML-Datei
|
isobuild.cmd als HTML-Datei |
|
Zum Menüeintrag 'Skripte etc.' - Druck-/Layout-Infos (hier: Quer-Format) - Stand: 06.10.2007
@ECHO OFF
IF NOT EXIST 5:\ (
ECHO ---------
ECHO - FEHLER: Virtuelles Laufwerk 5:\ existiert nicht
ECHO.
ECHO. Sie MUESSEN die Datei DLSTART.CMD aufrufen und
ECHO. dann die Option [I] ISO ... waehlen.
ECHO.
PAUSE
EXIT
)
ECHO.
ECHO. ISO-Dateien sind Abbilder von CDs. Diese werden auf eine CD[-RW]
ECHO. gebrannt, um eine funktionierende CD zu erhalten.
REM Definiere Zeitangaben
SET JJMMTT=%date:~9,4%-%date:~6,2%-%date:~3,2%
SET JJMMTT=%JJMMTT: =0%
SET SSMMSS=%time:~0,2%-%time:~3,2%-%time:~6,2%
SET SSMMSS=%SSMMSS: =0%
:CDIMAGE
REM Lade CDimage.exe ...
IF EXIST 5:\$OEM$\Tools\ISO\cdimage.exe GOTO :CDBURN
5:\%WGET_EXE% -q -P 5:\$OEM$\Tools\ISO http://www.heisig-it.de/pages/cdimage_pro.zip
REM Ersatz: http://win-zone.netfirms.com/MSFN/CDImage.zip
IF ERRORLEVEL 1 (
ECHO.
ECHO. CDimage.exe konnte nicht geladen werden.
GOTO :ENDE
)
IF NOT EXIST 5:\%UNZIP_EXE% (
ECHO.
ECHO. Das Tool unzip.exe fehlt.
ECHO. Bitte nutzen Sie 1 mal die Option [D] Downloads,
ECHO. um auch alle Tools zu laden.
GOTO :ENDE
) ELSE (
5:\%UNZIP_EXE% -o -q 5:\$OEM$\Tools\ISO\cdimage_pro.zip -d 5:\$OEM$\Tools\ISO\
)
DEL /Q 5:\$OEM$\Tools\ISO\*.zip
DEL /Q 5:\$OEM$\Tools\ISO\*.cmd
DEL /Q 5:\$OEM$\Tools\ISO\*.img
5:\$OEM$\Tools\ISO\cdimage.exe /? > 5:\$OEM$\Tools\ISO\CDIMAGE.TXT
:CDBURN
REM Lade CDburn.exe ...
IF EXIST 5:\$OEM$\Tools\ISO\cdburn.exe GOTO :ISO
5:\%WGET_EXE% -q -P 5:\$OEM$\Tools\ISO http://win-zone.netfirms.com/MSFN/CDBurn.zip
IF ERRORLEVEL 1 (
ECHO.
ECHO. CDburn.exe konnte nicht geladen werden.
GOTO :ISO
)
5:\$OEM$\Tools\ISO\cdburn.exe /? > 5:\$OEM$\Tools\ISO\CDBURN.TXT
:ISO
TITLE - ISO-Datei von Windows 2000 erstellen -
REM Sind die beiden Variablen definiert? ...
IF NOT DEFINED PfadISOCD GOTO :VARIABLEN
IF DEFINED LWBRENNER GOTO :ISOBUILD
:VARIABLEN
REM Erstelle Fehlerprotokoll
ECHO. --- > %TEMP%\ISO.TXT
ECHO. Fehler bei der Definition der Variablen: >> %TEMP%\ISO.TXT
ECHO. NOTWENDIGE VORBEREITUNGEN zur Erstellung einer ISO-Datei und einer neuen CD: >> %TEMP%\ISO.TXT
ECHO. --- >> %TEMP%\ISO.TXT
ECHO. In '%PfadWinCD%\dlstart.cmd' MUESSEN ZWEI Variablen vorhanden sein: >> %TEMP%\ISO.TXT
ECHO. 1. 'PfadISOCD' >> %TEMP%\ISO.TXT
ECHO. 2. 'LWBRENNER' >> %TEMP%\ISO.TXT
ECHO. --- >> %TEMP%\ISO.TXT
ECHO. Beispiele: >> %TEMP%\ISO.TXT
ECHO. SET PfadISOCD=H: >> %TEMP%\ISO.TXT
ECHO. SET PfadISOCD=H:\W2k_ISO >> %TEMP%\ISO.TXT
ECHO. bzw. >> %TEMP%\ISO.TXT
ECHO. SET LWBRENNER=K: >> %TEMP%\ISO.TXT
ECHO. >> %TEMP%\ISO.TXT
ECHO. ACHTUNG: Die Angaben MUESSEN OHNE '\' am Ende sein! >> %TEMP%\ISO.TXT
ECHO. >> %TEMP%\ISO.TXT
ECHO. Schauen Sie sich ggf. 'dlstart.cmd' im Ordner %PfadWinCD%\$OEM$\$1\Updates\Skripte_NEU an
>> %TEMP%\ISO.TXT
ECHO. und orientieren Sie sich an den dortigen Angaben. >> %TEMP%\ISO.TXT
ECHO. >> %TEMP%\ISO.TXT
ECHO. -- ACHTUNG: -- >> %TEMP%\ISO.TXT
ECHO. Nehmen Sie bei der Variablen PfadISOCD KEINESFALLS !! einen Ordener >> %TEMP%\ISO.TXT
ECHO. IN oder UNTERHALB von PfadWinCD = %PfadWinCD% >> %TEMP%\ISO.TXT
ECHO. Nehmen Sie ein Laufwerk, auf dem AUSREICHEND PLATZ ist. >> %TEMP%\ISO.TXT
ECHO. Kalkulieren Sie PRO CD-Image min. 650 MB. >> %TEMP%\ISO.TXT
ECHO. >> %TEMP%\ISO.TXT
REM Kopiere/Öffne Protokolldatei ...
COPY %TEMP%\ISO.TXT "%userprofile%\nt_adui\%JJMMTT%_%SSMMSS%_ISOfehler.LOG"
START /MAX %TEMP%\ISO.TXT
EXIT
:ISOBUILD
TITLE - ISO-Datei von Windows 2000 ERSTELLEN -
ECHO.
ECHO. Hier wird zur ISO-Erstellung das Tool CDIMAGE.EXE genutzt,
ECHO. das mit folgenden Optionen aufgerufen wird:
ECHO. -l CD-Name: W2k_plus_DE
ECHO. -j1 Dateisystem: Joliet UND ISO-9660
ECHO. -m CD-Groesse: Ignoriert 650MB-Grenze
ECHO. -b Boot-CD: Ja - mittels Bootsektordatei ..\2kbootim.age
ECHO. Modifikationen - siehe 'Auswahl:' ...
ECHO. -o Optimierung: Dateiduplikate werden nur EIN mal einbezogen
ECHO. -h Dateiumfang: Versteckte Dateien/Ordner werden einbezogen
ECHO.
ECHO. Eine Liste aller Optionen finden Sie in ..\$OEM$\Tools\ISO\CDIMAGE.TXT
ECHO. oder per ..\CDIMAGE.EXE /?.
ECHO.
ECHO.
ECHO. Berechne das gesamte Daten-Volumen in "%PfadWinCD%", wobei
ECHO. das Volumen der ISO-Datei wegen 'Bytes/Sektor' ca. 1-2%% hoeher liegen wird.
ECHO. Das Volumen der ISO-Datei kann durch 'Optionale Modifikationen' reduziert
ECHO. werden und wird vor dem Brennen angezeigt, damit Sie einen Hinweis zur Wahl
ECHO. eines geeigneten Rohlings erhalten.
ECHO.
DIR /a /-c /-p /s /w "%PfadWinCD%" > %temp%\w2kcdbyte1.txt
FIND /i "Datei" %temp%\w2kcdbyte1.txt > %temp%\w2kcdbyte2.txt
FOR /f "tokens=3" %%i in (%temp%\w2kcdbyte2.txt) do set sizebyte= %%i
SET /a sizeKB=%sizebyte:~0,-3%
IF %sizeKB% GTR 2147483 (
ECHO. Das Datenvolumen liegt oberhalb von 2 GB.
ECHO. Info: Eine weitere Berechnung findet nicht statt,
ECHO. da die Rechenmethode nur bis 2 GB funktioniert.
GOTO :AUSWAHL
)
SET /a sizeMB=%sizebyte% / (1024 * 1024)
ECHO. Datenvolumen von "%PfadWinCD%" = %sizeMB% MB
:AUSWAHL
ECHO.
ECHO.
ECHO Auswahl:
ECHO --------
ECHO.
ECHO. [N] Normale CD - Schreibt alle vorhandenen Daten 1:1 in die ISO-Datei
ECHO. [inkl. versteckter Dateien]
ECHO.
ECHO. Optionale Modifikationen
ECHO.
ECHO. [2] Optimieren - Mehrfach vorhandene Dateien werden nur 1 mal in ISO-Datei
ECHO. geschrieben [ist bei normaler W2k-CD NICHT erforderlich]
ECHO.
ECHO. [4] Verstecken - Datein/Ordner MIT gesetztem Archiv-Bit 'h'=hidden
ECHO. werden NICHT in die ISO-Datei geschrieben
ECHO.
ECHO. [6] = [2] + [4] = Optimieren + Verstecken = Beide Optionen
ECHO.
ECHO.
ECHO. [Q] Quit/Ende
ECHO.
:ISOBUILDMENU
SET /p Eingabe= Ihre Auswahl bitte:
IF /i '%Eingabe%'=='n' GOTO :OPT_N
IF /i '%Eingabe%'=='2' GOTO :OPT_2
IF /i '%Eingabe%'=='4' GOTO :OPT_4
IF /i '%Eingabe%'=='6' GOTO :OPT_6
IF /i '%Eingabe%'=='q' GOTO :QUITBUILD
GOTO :ISOBUILDMENU
:QUITBUILD
EXIT
:OPT_N
SET HIDDEN=-h
GOTO :BUILDISO
:OPT_2
SET OPTIMIZE=-o
SET HIDDEN=-h
GOTO :BUILDISO
:OPT_4
GOTO :BUILDISO
:OPT_6
SET OPTIMIZE=-o
GOTO :BUILDISO
:BUILDISO
SET ISO=W2k_plus_CD_%JJMMTT%_%SSMMSS%.ISO
ECHO.
ECHO. Erstelle ISO-Datei ...
5:\$OEM$\Tools\ISO\CDIMAGE.EXE -lW2k_plus_DE %HIDDEN% -j1 -m -b5:\2kbootim.age %OPTIMIZE%
%PfadWinCD% "%PfadISOCD%\%ISO%"
ECHO.
IF ERRORLEVEL 1 (
ECHO. Es ist ein Fehler aufgetreten.
ECHO. Die Datei konnte nicht [komplett] erstellt werden.
ECHO. Sie wird - falls vorhanden - entfernt.
DEL "%PfadISOCD%\%ISO%"
ECHO.
ECHO. Ein Tastendruck beendet dieses Fenster ...
PAUSE >NUL
EXIT
) ELSE (
ECHO. Die ISO-Datei wurde erstellt. Sie koennen diese nun mit Ihrem
ECHO. Brennprogramm auf eine CD[-RW] brennen, um eine aktuelle und
ECHO. BOOTBARE Win2000-CD [Name: 'W2k_plus_DE'] zu erhalten.
)
:ISOBURN
TITLE - ISO-Datei von Windows 2000 BRENNEN -
IF NOT EXIST 5:\$OEM$\Tools\ISO\cdburn.exe (
ECHO.
ECHO. CDburn.exe ist nicht vorhanden.
ECHO. Daher sind die Brenn-Optionen dieses Skripts nicht nutzbar.
GOTO :ENDE
)
ECHO.
ECHO. Alternativ:
ECHO. Wenn Sie die SOEBEN ERSTELLTE ISO-Datei brennen wollen, stehen auch die
ECHO. nachfolgenden Optionen bereit, die aber eventuell NICHT auf IHREM Brenner
ECHO. funktionieren.
ECHO.
ECHO. ACHTUNG - Rohling-Auswahl:
DIR /-c "%PfadISOCD%\%ISO%" > %temp%\w2kcdisobyte1.txt
FIND /i "Datei" %temp%\w2kcdisobyte1.txt > %temp%\w2kcdisobyte2.txt
FOR /f "tokens=3" %%i in (%temp%\w2kcdisobyte2.txt) do set sizeiso= %%i
SET /a sizeisoKB=%sizeiso:~0,-3%
IF %sizeisoKB% GTR 2147483 (
ECHO. Das Datenvolumen liegt oberhalb von 2 GB.
ECHO. Info: Eine weitere Berechnung findet nicht statt,
ECHO. da die Rechenmethode nur bis 2 GB funktioniert.
GOTO :ISOAUSWAHL
)
SET /a sizeisoMB=%sizeiso% / (1024 * 1024)
ECHO. Die ISO-Datei hat einen Umfang von ... %sizeisoMB% MB.
:ISOAUSWAHL
ECHO.
ECHO Auswahl:
ECHO --------
ECHO. [R] CD-R brennen - MUSS LEER sein
ECHO.
ECHO. [W] CD-RW brennen - wird vorher geloescht
ECHO.
ECHO.
ECHO. [Q] Quit/Ende
ECHO.
:ISOBURNMENU
SET /p Eingabe= Ihre Auswahl bitte:
IF /i '%Eingabe%'=='r' GOTO :BURN_CD
IF /i '%Eingabe%'=='w' GOTO :BURN_CDRW
IF /i '%Eingabe%'=='q' GOTO :QUITBURN
GOTO :ISOBURNMENU
:QUITBURN
EXIT
:BURN_CD
ECHO.
ECHO. Erstelle CD-R ...
ECHO.
5:\$OEM$\Tools\ISO\CDBURN.EXE %LWBRENNER% "%PfadISOCD%\%ISO%" -sao
ECHO Errorlevel ist: %errorlevel%
GOTO :ENDE
:BURN_CDRW
ECHO.
ECHO. Erstelle CD-RW ...
ECHO.
5:\$OEM$\Tools\ISO\CDBURN.EXE %LWBRENNER% -erase "%PfadISOCD%\%ISO%"
ECHO Errorlevel ist: %errorlevel%
GOTO :ENDE
:ENDE
ECHO.
ECHO. Bitte schliessen Sie dieses Fenster per Tastendruck
ECHO. und NICHT per Klick auf [X] oben rechts im Fenstertitel.
PAUSE >NUL
EXIT
Jürgen Terlinden - Feedback