patches.cmd als HTML-Datei

Zum Menüeintrag 'Skripte etc.'   -   Druck-/Layout-Infos (hier: Quer-Format)   -   Stand: 30.09.2006

@echo off
TITLE Starte das Update-Skript ...

REM Erstelle zu Prüfzwecken ...
SET ZEIT="%date:~9,4%-%date:~6,2%-%date:~3,2%_%time:~0,2%-%time:~3,2%-%time:~6,2%"
REM ... den Ordner ...
MKDIR %systemdrive%\$_INST\I_%ZEIT%
REM ... und darin eine Infodatei.
ECHO. > %systemdrive%\$_INST\I_%ZEIT%\Ordnerinfo.txt
ECHO. NACH einer Neuinstallation kann >> %systemdrive%\$_INST\I_%ZEIT%\Ordnerinfo.txt
ECHO. dieser Ordner entfernt werden. >> %systemdrive%\$_INST\I_%ZEIT%\Ordnerinfo.txt

ECHO Starte das Skript zum Updaten ...
START /WAIT /MAX CALL %systemdrive%\Updates\updaten.cmd
ECHO. Ok. Der Vorgang ist abgeschlossen.
ECHO.

:DIENSTE
IF EXIST "%USERPROFILE%\ntsvcfg" GOTO :ENDE
TITLE Konfiguriere die Windows-Dienste ...

REM Die Installationen sind fertig. Die Konfiguration der Windows-Dienste
REM fehlt noch. Dazu wird gleich das Skript 'svc2kxp.cmd' aufgerufen.
REM H I N W E I S E, falls Sie das Skript O H N E Parameter starten:
REM Beenden Sie das Skript wie gefordert mit einem Tastendruck.
REM Beenden Sie das Skript NICHT per Klick auf [X] oben rechts im Fenstertitel!
REM GOTO :ENDE
CALL %windir%\system32\svc2kxp.cmd /ALL
REM
REM Setze nun den Status von Diensten neu, denn falls beim Skript
REM Option 3 = Parameter /ALL genutzt wurde, sind sie z.T. deaktiviert.
REM Zum Funktionieren des MBSA erforderlich:
%windir%\system32\SC.EXE config lanmanserver start= auto
REM
REM Zum Funktionieren von Windows-Update (V6) erforderlich:
REM 1.: Automatische Updates auf Automatisch + Gestartet
%windir%\system32\SC.EXE config wuauserv start= auto
%windir%\system32\SC.EXE start wuauserv
REM 2.: Intelligenter Hintergrundübertragungsdienst (BITS) auf Manuell
%windir%\system32\SC.EXE config bits start= demand


:ENDE
REM Lösche Hilfsordner und Skript - starte PC neu
IF EXIST %systemdrive%\$_INST RMDIR /S /Q %systemdrive%\$_INST
%windir%\system32\psshutdown.exe -r -t 25 -m "Der Computer MUSS neu gestartet werden. FALLS die Windows-Dienste konfiguriert wurden, befindet sich das System nun in einem sicheren Zustand und kann online gehen."
DEL "%ALLUSERSprofile%\Startm~1\Programme\Autostart\patches.cmd"
EXIT

Jürgen Terlinden  -  Feedback