#*******************************************
# MacVersion = 1.0
# MacDescription = Autoroute Export
# MacAuthor = Michael Zielinski
# MacFileName = Autoroute_export.gsk
# MacUrl =
#*******************************************
# Variablen setzen - Hier können bei Bedarf Änderungen gemacht werden
$filExport = "D:\Caches.csv"
$lang = 1 #set to 1 for german autoroute

#Hier kann ein GSAK-FIlter eingesetzt werden...
#FILTER Name="Multis"

##################################

IF Not ( $_FilterActive ) 
   CANCEL Msg="Kein Filter ausgewählt - die ganze Datenbank ist zu viel..."
endif

SHOWSTATUS msg="Exportiere..."

IF FileExists($filExport) 
  FileErase file=$filExport
endif

if $lang = 0 
  $_txt1 = "Name"
  $_txt2 = "Latitude"
  $_txt3 = "Longitude"
  $_txt4 = "Name 2"
  $_txt5 = "URL"
else
  $_txt1 = "Name"
  $_txt2 = "Breitengrad"
  $_txt3 = "Längengrad"
  $_txt4 = "Name 2"
  $_txt5 = "URL"
endif
$result = TextOut($filExport,"none","tab")
# Just in case file permission error or something test for error
IF Left($result,7) = "*Error*"
  Pause Msg=$result
  Cancel
EndIf  

Goto Position=Top
while not($_eol)
  If $d_HasCorrected  = True
     $_txt1 = "%code %typ1%con1%dif1a%ter1a*"
    else
     $_txt1 = "%code %typ1%con1%dif1a%ter1a"
  Endif
  $_txt2 = Replace(".", ",", $d_Latitude , True)
  $_txt3 = Replace(".", ",", $d_longitude, True)
  $_txt4 = $d_name
  $_txt5 = $d_Url
  $result = TextOut($filExport,"None","tab")
  # Just in case file permission error or something test for error
  IF Left($result,7) = "*Error*"
    Pause Msg=$result
    Cancel
  EndIf  
  Goto position=next
Endwhile

Cancel Msg="Now you can import $filExport into Autoroute"