#*******************************************
# MacVersion = 1.0
# MacDescription = Autoroute Import
# MacAuthor = Michael Zielinski
# MacFileName = Autoroute_import.gsk
# MacUrl =
#*******************************************
# Variablen setzen - Hier können bei Bedarf Änderungen gemacht werden
$axe = "d:\map.axe" #Defaultname der Axe-Datei
$sort = 10 #usersort start
$inc = 1 #usersort increment
$udata2 = 1 # auf 1 setzen um den Namen der Axe-Datei in  userdata2 zu speichern - 0 für ausschalten

#******************************************
USERFLAG type=clear range=all 
 
$Msg = "Select msroute axe file" + $_NewLine
INPUT Msg=$Msg Default=$axe VarName=$axe Browse=File

#####9#9#9##9
IF NOT(FileExists($axe))
  CANCEL Msg=Keine Autoroutedatei $axe gefunden
endif
 
#debug status=on
 
Set $gdb = left($axe,len($axe)-4) + ".gdb"
Set $csv = $_Install + "\macros\autoroute.csv"

#debug status=on
Set $axe2 = left($axe,len($axe)-4)
set $axe2 = replace("\"," ",$axe2,true)
$cnt = 1
while Extract($axe2, " ",$cnt) <> ""
  $cnt = $cnt + 1
endwhile
set $axe2 = Extract($axe2, " ",$cnt - 1)


Set $parm = quote($_Install + "\gpsbabel.exe") + " -r -i msroute -f " + quote($axe) + " -o gdb -F "  + quote($gdb) + " -o csv -F " + quote($csv) 
GOSUB Name=mzbabel
#debug status=on



FileRead File=$csv
  $code = Extract($line, ",", 3)  
  $code = AllTrim($Code) #delete leading Blank  
  $code =  Extract($code, " ",1)
  if seek($code) # make sure code is valid before updating user data
     $d_UserSort =  $sort
     $d_UserFlag = True
	 if $udata2 = 1
	   $d_User2 = $axe2
	 endif
     $sort = $sort + $inc
  else
     MsgOk Msg=Cache nicht gefunden in GSAK-Datenbank $code
  endif   
EndRead
 

IF FileExists($csv) 
  FileErase file=$csv
endif

#########################################

BEGINSUB Name=mzbabel
  $babel = $_Install + "\babel.cmd"
  IF FileExists($babel) 
    FileErase file=$babel
  endif
  SET $Data = AppendFile($babel , $parm + $_NewLine )
 # SET $Data = AppendFile($babel , "more" + $_NewLine )
  RUNPGM Pgm=$babel  Wait=Yes
ENDSUB